home *** CD-ROM | disk | FTP | other *** search
/ User's Choice Windows CD / User's Choice Windows CD (CMS Software)(1993).iso / windows4 / pcproj.zip / RESOURCE.CLS < prev    next >
Text File  |  1988-11-30  |  5KB  |  199 lines
  1. /* Resources are used to complete Tasks.  Resources have
  2.    associated costs.  Examples of Resources would be a 
  3.    person or a machine.  Resources are kept in a collection.
  4.  
  5.    When assigning resources their availability and usage
  6.    should be tracked.  This is not yet implemented.
  7. */!!
  8.  
  9. inherit(Object, #Resource, #(
  10. name          /* description   */
  11. fixedCost     /* per usage     */
  12. variableCost  /* per time used */
  13. references    /* set of Tasks  */
  14. maximum       /* Not yet used  */
  15. usage         /* Not yet used  */), 2, nil)!!
  16.  
  17. now(ResourceClass)!!
  18.  
  19. /* Create a new Resource. */
  20. Def  new(self)
  21. { 
  22.   ^init(new(self:Behavior));
  23. }!!
  24.  
  25. now(Resource)!!
  26.  
  27. /* Delete a resource.  First check to see if it is
  28.    used anywhere and check with the user. */
  29. Def  delete(self, project)
  30. { 
  31.   if size(references) = 0
  32.     cor yesNoBox(loadString(PW_WARNING),
  33.                  loadString(PW_RESOURCE) + " " + name +
  34.                  loadString(PW_RESUSE) + CR_LF +
  35.                  loadString(PW_DELETE)) == IDYES
  36.      do(references,
  37.        {using(aTask) 
  38.         removeResource(aTask, self);
  39.      });
  40.     remove(project.resources, self.name);    
  41.   endif;      
  42. }!!
  43.  
  44. /* Return a string of all activities that reference a resource. */
  45. Def  getRefsString(self | str)
  46. { 
  47.   str := "";
  48.   do(references,
  49.     {using(ref) 
  50.      str := str + getName(ref) + " ";
  51.   });
  52.  
  53.   if size(str) > 20 then
  54.     str := subString(str, 0, 18) + "..";
  55.   endif;
  56.   ^str;
  57. }!!
  58.  
  59. /* Return a string to be used as a caption in a window. */
  60. Def  makeCaption(self)
  61. {
  62.   ^loadString(PW_RESOURCE) + ": "+getName(self);
  63. }!!
  64.  
  65. /* Get the amount used of a resource. */
  66. Def  getUsed(self | used)
  67. { 
  68.   used := 0;
  69.   do(references,
  70.     {using(aTask)
  71.      used := used + getTime(aTask);
  72.    });
  73.   ^used;
  74. }!!
  75.  
  76. /* Summarize useful information on a single line. */
  77. Def  getInfoLine(self | used, str)
  78. {
  79.   used := getUsed(self);
  80.   if maximum cand used > maximum
  81.      str := "*";
  82.   else
  83.      str := " ";
  84.   endif;
  85.   ^str 
  86.    + field(name, 6) 
  87.    + field(asString(getMaximum(self)), 3) + " " 
  88.    + field(asString(used), 3) + " "
  89.    + field(asString(getFixedCost(self)), 3) + " " 
  90.    + field(asString(getVariableCost(self)), 3) + " "
  91.    + field(getRefsString(self),20);
  92. }!!
  93.  
  94. /* Set the values of a resource. 
  95.    Values is an array of name, maximum,
  96.    fixedCost, variableCost. */
  97. Def  setValues(self, values)
  98. {
  99.   name := values[0];
  100.   maximum := values[1];
  101.   setFixedCost(self, values[2]);
  102.   setVariableCost(self, values[3]);
  103. }!!
  104.  
  105. /* Display and edit the resource information. 
  106.    The dialog should define methods run() and setEditItem().
  107. */
  108. Def  editInfo(self | dlg, retValue)
  109. {
  110.   showWaitCurs();
  111.   dlg := new(ResDialog); 
  112.   setEditItem(dlg, self);
  113.   retValue := run(dlg, ThePort);
  114.   showOldCurs();
  115.   ^retValue;
  116. }!!
  117.  
  118. /* Print a resource. */
  119. Def  printOn(self, aStream)
  120. { 
  121.   printOn(name, aStream);
  122. }!!
  123.  
  124. /* Set the name of a resource. */
  125. Def  setName(self, aName)
  126. { name := aName;
  127. }!!
  128.  
  129. /* Set the variableCost of a resource.  If necessary,
  130.    update the cost of any Tasks that reference it. */
  131. Def  setVariableCost(self, aCost | oldCost)
  132. { 
  133.   if (aCost <> variableCost)
  134.     oldCost := variableCost;
  135.     variableCost := aCost;
  136.     do(references,
  137.       {using(aTask) updateCost(aTask, variableCost - oldCost);
  138.     });
  139.   endif;
  140. }!!
  141.  
  142. /* Get the variableCost of a resource. */
  143. Def  getVariableCost(self)
  144. { ^variableCost;
  145. }!!
  146.  
  147. /* Set the fixedCost of a resource.  If necessary,
  148.    update the cost of any Tasks that reference it. */
  149. Def  setFixedCost(self, aCost | oldCost)
  150. { 
  151.   if (aCost <> fixedCost)
  152.     oldCost := fixedCost;
  153.     fixedCost := aCost;
  154.     do(references,
  155.       {using(aTask) updateCost(aTask, fixedCost - oldCost);
  156.     });
  157.   endif;
  158. }!!
  159.  
  160. /* Get the fixedCost of a resource. */
  161. Def  getFixedCost(self)
  162. { ^fixedCost;
  163. }!!
  164.  
  165. /* Remove a reference to a resource. */
  166. Def  removeReference(self, aTask)
  167. { remove(references, aTask);
  168. }!!
  169.  
  170. /* Add a reference to a resource. */
  171. Def  addReference(self, aTask)
  172. { add(references, aTask);
  173. }!!
  174.  
  175. /* Get the maximum available of a resource. */
  176. Def  getMaximum(self)
  177. { if maximum
  178.     ^maximum;
  179.   else
  180.     ^"";
  181.   endif;
  182. }!!
  183.  
  184. /* Get the name of a resource. */
  185. Def  getName(self)
  186. { ^name;
  187. }!!
  188.  
  189. /* Initialize a new resource. */
  190. Def  init(self)
  191. {
  192.   name := "";
  193.   maximum := nil;              /* unlimited */
  194.   variableCost := 0;
  195.   fixedCost := 0;
  196.   references := new(Set, 10);  /* where used */
  197. }!!
  198.  
  199.